How do I print multiple variables in a string?

  • Say I have some variables that I want to print out to the terminal, what's the easiest way to print them in a string?

    Currently I do something like this:

    Serial.print("Var 1:");Serial.println(var1);
    Serial.print(" Var 2:");Serial.println(var2);
    Serial.print(" Var 3:");Serial.println(var3);
    

    Is there a better way to do this?

    An idea, but I don't know if it would work, is some modification of this... Again, I don't know if this is supported on Arduino: http://stackoverflow.com/questions/804288/creating-c-formatted-strings-not-printing-them

  • asheeshr

    asheeshr Correct answer

    7 years ago

    ardprintf is a function that I hacked together which simulates printf over the serial connection. This function (given at the bottom) can be pasted in the beginning of the files where the function is needed. It should not create any conflicts.

    It can be called similar to printf. See it in action in this example:

    void setup()
    {
      Serial.begin(9600);
    }
    
    void loop()
    {
      int l=2;
      char *j = "test";
      long k = 123456789;
      char s = 'g';
      float f = 2.3;
    
      ardprintf("test %d %l %c %s %f", l, k, s, j, f);
    
      delay(5000);
    
    }
    

    The output as expected is:

    test 2 123456789 g test 2.30
    

    The function prototype is:

    int ardprintf(char *, ...);
    

    It returns the number of arguments detected in the function call.

    This is the function definition:

    #ifndef ARDPRINTF
    #define ARDPRINTF
    #define ARDBUFFER 16
    #include <stdarg.h>
    #include <Arduino.h>
    
    int ardprintf(char *str, ...)
    {
      int i, count=0, j=0, flag=0;
      char temp[ARDBUFFER+1];
      for(i=0; str[i]!='\0';i++)  if(str[i]=='%')  count++;
    
      va_list argv;
      va_start(argv, count);
      for(i=0,j=0; str[i]!='\0';i++)
      {
        if(str[i]=='%')
        {
          temp[j] = '\0';
          Serial.print(temp);
          j=0;
          temp[0] = '\0';
    
          switch(str[++i])
          {
            case 'd': Serial.print(va_arg(argv, int));
                      break;
            case 'l': Serial.print(va_arg(argv, long));
                      break;
            case 'f': Serial.print(va_arg(argv, double));
                      break;
            case 'c': Serial.print((char)va_arg(argv, int));
                      break;
            case 's': Serial.print(va_arg(argv, char *));
                      break;
            default:  ;
          };
        }
        else 
        {
          temp[j] = str[i];
          j = (j+1)%ARDBUFFER;
          if(j==0) 
          {
            temp[ARDBUFFER] = '\0';
            Serial.print(temp);
            temp[0]='\0';
          }
        }
      };
      Serial.println();
      return count + 1;
    }
    #undef ARDBUFFER
    #endif
    

    **To print the % character, use %%.*


    Now, available on Github gists.

    Nice idea, although I felt it could be more minimalist, so I rewrote this version to one without buffering. Anyone interested can check out the gist: https://gist.github.com/EleotleCram/eb586037e2976a8d9884

  • I wouldn't normally put two answers to a question, but I only just found this today, where you can use printf without any buffer.

    // Function that printf and related will use to print
    int serial_putchar(char c, FILE* f) {
        if (c == '\n') serial_putchar('\r', f);
        return Serial.write(c) == 1? 0 : 1;
    }
    
    FILE serial_stdout;
    
    void setup(){
        Serial.begin(9600);
    
        // Set up stdout
        fdev_setup_stream(&serial_stdout, serial_putchar, NULL, _FDEV_SETUP_WRITE);
        stdout = &serial_stdout;
    
        printf("My favorite number is %6d!\n", 12);
    }
    
    void loop() {
      static long counter = 0;
      if (millis()%300==0){
        printf("millis(): %ld\tcounter: %ld (%02X)\n", millis(), counter, counter++);
        delay(1);    
      }
    }
    

    This still has the floating point limitation.

    edit: I thought I would do a little testing on this, and it works quite well. I added a better test to the loop with formatted output.

    Oh man, that's cool. printf is a whole lot safer than sprintf. It gives you format strings for free, which is great. Cool trick. Thanks. (Voted)

    One question: In your `serial_putchar` function, why not make the return statement `return !Serial.write(c);`? Isn't that cleaner than a trinary operator for inverting the sense of a boolean return value?

    That's a good point and I like it. The code wasn't mine and I pasted it as I found it.

    Thanks for the `serial_putchar` function. It works a treat. :-) Can you fix the _floating point limitation_?

  • This is probably not better, just different. You can use the String object for output. These objects allow concatenation and support automatic typecasting.

    Serial.begin(9600);
    String label = "Var";
    const byte nValues = 3;
    int var[nValues] = {36, 72, 49};
    
    for (int i = 0; i < nValues; i++) {
        String stuff = label + i + ": ";
        Serial.println(stuff + var[i]);
    }
    

    Obviously it's important to be careful of memory limits. Lots of concatenations and other string operations in one place can use a surprising amount of space.

    @PeterR.Bloomfield Absolutely true! That's the reason why I mentioned that this variant isn't better ;)

  • I usually used Tabs to make things line up better in the Serial. Having things line up like I do allow the arduino to fire as fast as possible while being able to notice certain changes in the variables.

    Try something like this:

    Serial.println("Var 1:\tVar 2tVar 3:");
    Serial.print("\t");
    Serial.print(var1);
    Serial.print("\t");
    Serial.print(var2);
    Serial.print("\t");
    Serial.print(var3);
    Serial.println();
    

    Or something like this:

    Serial.print("Var 1:");Serial.println(var1);
    Serial.print("\tVar 2:");Serial.println(var2);
    Serial.print("\tVar 3:");Serial.println(var3);
    

    Honestly, I do the same ("\t" and "\n") and normally avoid the code-bloating String object bells and whistles.

    @KlausWarzecha, I rarely give the variable name as they're in nice columns. Also make it easier to see random print outs that don't match this syntax

  • I only use this for debugging but:

    int a = 10;
    int b = 20;
    Serial.println("a = " + String(a) + " and b = " + String(b));
    

    what is String$?

    LMFTFM (Let me fix that for me).

  • I am newbie in Arduino world, but I recently found that this is just a regular C++ (without exceptions and probably polymorphism). But you still can enjoy templates. So my solution is to use following templates:

    void myprint(void)
    {
      Serial.println("");
    }
    
    template<typename ...Args>
    void myprint(const uint64_t & val, Args && ...args)
    {
      serialPrintUint64(val);
      myprint(args...);
    }
    
    template<typename T, typename ...Args>
    void myprint(const T & t, Args && ...args)
    {
      Serial.print(t);
      myprint(args...);
    }
    
    ....
    
    // somewhere in your code
    myprint("type: ", results.decode_type, 
            "\t value: ", results.value, 
            "\t addr: ", results.address,
            "\t cmd: ", results.command);
    

    Nice thing here is that it does not use any extra memory and extra processing here.

  • I usually (painfully) stick with multiple lines of Serial.print but when it becomes convoluted I go back to sprintf. It's annoying in that you have to have an available buffer for it.

    Usage is as simple (??) as:

    char buffer[35]; // you have to be aware of how long your data can be
                     // not forgetting unprintable and null term chars
    sprintf(buffer,"var1:%i\tvar2:%i\tvar3:%i",var1,var2,var3);
    Serial.println(buffer);
    

    A word of warning though, it doesn't (by default) support floating types.

    sprintf is a horrible abomination. Not type safe, easy to overrun your buffers, etc, etc. It's a tool from the 1960s. That said, I use it too, but it is not for the faint of heart....

    To avoid overrun, use snprintf... BTW most of the moder IDEs (NOT the Arduino IDE) will check the string format against the provided variable types, and will throw a warning.

  • Using Streaming.h, in place of

    Serial.print("Var 1:");Serial.println(var1);
    Serial.print(" Var 2:");Serial.println(var2);
    Serial.print(" Var 3:");Serial.println(var3);
    

    one can write

    Serial << "Var 1:" << var1) << " Var 2:" << var2 << " Var 3:" << var3 << endl;
    

    The definition of << in Streaming.h in effect translates that into a series of ordinary Serial.print() calls. That is, << is syntactic sugar, implemented without increasing code size.

    If you don't have Streaming.h installed, get Streaming5.zip from arduiniana.org. Unzip it in your libraries directory, for example in ~/sketchbook/libraries. Add the line #include <Streaming.h> within sketches where you use << as a stream operator.

    Base-conversion specifiers _HEX, _DEC, _OCT, and _BIN are provided, as well as a _FLOAT function (with number of decimal places) and endl. For example, to print latitude and longitude values in a form like "Your coordinates are -23.123, 135.4567” one could write:

    Serial << "Your coordinates are " << _FLOAT(latitude,3) << ", " << _FLOAT(longitude,4) << endl;
    

    This could also be written as

    Serial << F("Your coordinates are ") << _FLOAT(latitude,3) << ", " << _FLOAT(longitude,4) << endl;
    

    which would keep the longer string in PROGMEM instead of bringing it into RAM.

    Note, Streaming.h doesn't build any strings as such; it just delivers the text of its <<-arguments to a stream. A PString class at arduiniana can build strings from stream inputs, if strings instead of streamed output are desired or needed.

  • The usage will depend of the data type of your variables.

    If they are int, it would be %d or %i If they are string, it would be %s

    Wrapper for printf

    You can change the limit based on your requirements

    #include <stdarg.h>
    void p(char *fmt, ... ){
        char buf[128]; // resulting string limited to 128 chars
        va_list args;
        va_start (args, fmt );
        vsnprintf(buf, 128, fmt, args);
        va_end (args);
        Serial.print(buf); // Output result to Serial
    }
    

    Source: https://playground.arduino.cc/Main/Printf

    Usage examples:

    p("Var 1:%s\nVar 2:%s\nVar 3:%s\n", var1, var2, var3); // strings
    p("Var 1:%d\nVar 2:%d\nVar 3:%d\n", var1, var2, var3); // numbers
    

    ESP8266

    Its built-in in Serial class of the framework. No need for additional library or function.

    // strings
    Serial.printf("Var 1:%s\nVar 2:%s\nVar 3:%s\n", var1, var2, var3);
    // numbers
    Serial.printf("Var 1:%d\nVar 2:%d\nVar 3:%d\n", var1, var2, var3);
    

    More details about formatting tips on the printf format reference page : http://www.cplusplus.com/reference/cstdio/printf/

    \n is the escape sequence for the line feed.

    Escape sequences are used to represent certain special characters within string literals and character literals.

    Source: http://en.cppreference.com/w/cpp/language/escape

    [EDIT] - As @Juraj mentioned, it's not available on most of the AVR modules. So I added ESP8266 mention and a printf wrapper for common AVR modules

    this is not true. there is no Serial class. printf would be in Print class, but it is not in the most used AVR package

    @Juraj you are right, I've only tested it on ESP8266 which have it (link) and thought it was from arduino core. Will update my answer accordingly

    for the p function I would add one more downvote if it was possible.

    this is an old question and I can\t judge the old answers because I don't know what was available in 2014. but now there are libraries for wrapping a Print stream in a Print stream with printf implementation.

  • One possible solution is:

    Serial.println((String)"Var 1:" + var1 + " Var 2:" + var2 + " Var 3:" + var3);

    I like this method and I use it a lot. I'm giving you a plus 1.

License under CC-BY-SA with attribution


Content dated before 6/26/2020 9:53 AM